#
# @(#)local.login 1.4     98/02/06 SMI
#
stty -istrip 

#
#  Modified for DMCL use. Version 981201
#
set cpuArch=`uname -p`

#
#  Solaris Paths
#  N.B. /usr/ucb names intersect with SVr4 names
#
# path to executables, shared libraries and manpages
setenv PATH /usr/bin:/usr/sbin:/usr/ucb
setenv LD_LIBRARY_PATH /usr/lib
setenv MANPATH /usr/man


#
# CDE
#
if ( $?dtHome == 0 ) then
	set dtHome="/usr/dt"
endif
# Put after existing paths
if ( -d ${dtHome} ) then
    setenv XFILESEARCHPATH ${XFILESEARCHPATH}:${dtHome}/%T/%N%S
    setenv PATH ${PATH}:${dtHome}/bin
    setenv MANPATH ${MANPATH}:${dtHome}/man
    setenv LD_LIBRARY_PATH ${LD_LIBRARY_PATH}:${dtHome}/lib
endif


#
# Openwin
#
if ( $?OPENWINHOME == 0 ) then
	setenv OPENWINHOME "/usr/openwin"
endif
# Put after existing paths
if ( -d ${OPENWINHOME} ) then
   setenv HELPPATH ${OPENWINHOME}/lib/locale:${OPENWINHOME}/lib/help
   # path to X resources (e.g., app-defaults)
   setenv XFILESEARCHPATH ${OPENWINHOME}/lib/locale/%L/%T/%N%S:${OPENWINHOME}/lib/%T/%N%S
   setenv PATH ${PATH}:/usr/openwin/bin
   setenv LD_LIBRARY_PATH ${LD_LIBRARY_PATH}:${OPENWINHOME}/lib
   setenv MANPATH ${MANPATH}:${OPENWINHOME}/man
endif


#
#  Personal Path
#  This path before DMCL local paths to allow user to override
#
setenv PATH ${PATH}:$HOME/bin/${cpuArch}
setenv LD_LIBRARY_PATH ${LD_LIBRARY_PATH}:$HOME/lib/${cpuArch}
setenv MANPATH ${MANPATH}:$HOME/man

#
#  DMCL and Summertime_XX (DMCL NFS PATH organization)
#
#  In addition to the software included with Solaris host installation:
#
#    /opt       - Solaris optional packages (e.g., Sun Compilers)
#    /opt/local - Collections of "packaged" software from the Internet, 
#                 e.g., GNU software such as gzip.
#                 (/opt/local is a link to /opt/Summertime_XX.${cpuArch})
#                 (See ~dadmin/DMCL_Software/S98/sysadmin.sparc/local.profile)
#    /usr/local - Un-"packaged" software. This includes updates
#                 and additions to the software in /opt/local
#
#
set local0=/usr/local
set local1=/opt/local			# Current Summertime
set local2=/opt/local.old		# Previous Summertime
setenv TEXPATH ${local0}/teTeX

set xfspSfx=lib/X11/%T/%N%S
setenv XFILESEARCHPATH ${XFILESEARCHPATH}:${local0}/${xfspSfx}:${local1}/${xfspSfx}:${local2}/${xfspSfx}
setenv PATH ${PATH}:${local0}/bin:${local1}/bin:${local2}/bin:$TEXPATH/bin
setenv LD_LIBRARY_PATH ${LD_LIBRARY_PATH}:${local0}/lib:${local1}/lib:${local2}/lib:$TEXPATH/lib 
setenv MANPATH ${MANPATH}:${local0}/man:${local1}/man:${local2}/man:$TEXPATH/man

#
#  Solaris Tools / Sun Workshop paths
#
#  When you use the Sun compilers, these should go at the 
#  head of the path so as to avoid interference from identically
#  named tools (e.g. some GNU configurations). 
#
set wsBase=/opt/SUNWspro	# Production Sun compilers
setenv PATH ${wsBase}/bin:/usr/ccs/bin:${PATH}
setenv LD_LIBRARY_PATH ${wsBase}/lib:/usr/ccs/lib:${LD_LIBRARY_PATH}
setenv MANPATH ${wsBase}/man:${MANPATH}

#
# if possible, start the windows system.  Give user a chance to bail out
#
if ( "`tty`" == "/dev/console" ) then

	if ( "$TERM" == "sun" || "$TERM" == "AT386" ) then

		if ( ${?OPENWINHOME} == 0 ) then	 
			setenv OPENWINHOME /usr/openwin
		endif			    

		echo ""
		echo -n "Starting OpenWindows in 5 seconds (type Control-C to interrupt)"
		sleep 5
		echo ""
		$OPENWINHOME/bin/openwin
		clear		# get rid of annoying cursor rectangle
		logout		# logout after leaving windows system

	endif

endif